TOOL_テキストファイル情報収集_フォーム入力情報取得クラス

  • ソース

Option Compare Database
Option Explicit

' GFI_FormValueObject
' フォームの入力情報を格納する

Private FolderPath As String
Private FilePattern As String
Private hasHeaderLine As Boolean
Private IsListReset As Boolean

Private HasValidateError As Boolean
Private ValidateErrorMsg As String

Private Sub class_initialize()
    Dim mForm As Form
    Dim fFolderPath As String
    
    ' 1.値の初期化
    HasValidateError = False
    ValidateErrorMsg = ""
    
    ' 2.フォームの指定
    Set mForm = Forms("ファイル情報取得フォーム")
    
    ' 3.フォルダパスの設定
    fFolderPath = Nz(mForm.Controls("フォルダパス項目").Value)
    If Not (Len(fFolderPath) > 0) Then
        ' 値が空文字の場合エラー
        HasValidateError = True
        ValidateErrorMsg = "フォルダパスが指定されていません"
        Exit Sub
    ElseIf Dir(mForm.Controls("フォルダパス項目").Value, vbDirectory) = "" Then
        ' 指定のフォルダが存在しない場合エラー
        HasValidateError = True
        ValidateErrorMsg = "指定されたフォルダパスが存在していません"
        Exit Sub
    Else
        ' フォルダパスを設定
        FolderPath = mForm.Controls("フォルダパス項目").Value
    End If
    
    ' 4.ファイルパターン
    If mForm.Controls("検索ファイル").Value = 1 Then
        ' ファイルパターンをTXTファイルに設定
        FilePattern = "*.txt"
    ElseIf mForm.Controls("検索ファイル").Value = 2 Then
        ' ファイルパターンをCSVファイルに設定
        FilePattern = "*.csv"
    Else
        ' ファイルパターン不明としてエラー
        HasValidateError = True
        ValidateErrorMsg = "検索ファイルが不明です"
        Exit Sub
    End If
    
    ' 5.ヘッダー行有無
    If mForm.Controls("チェック_ヘッダー行有無").Value <> False Then
        hasHeaderLine = True
    Else
        hasHeaderLine = False
    End If
    
End Sub

' 以下値取得用

Public Function GetFolderPath() As String
    GetFolderPath = FolderPath
End Function

Public Function GetFilePattern() As String
    GetFilePattern = FilePattern
End Function

Public Function GetHasHeaderLine() As Boolean
    GetHasHeaderLine = hasHeaderLine
End Function

Public Function GetHasValiateError() As Boolean
    GetHasValiateError = HasValidateError
End Function

Public Function GetValidateErrorMsg() As String
    GetValidateErrorMsg = ValidateErrorMsg
End Function

2013/05/15 全面改訂





最終更新:2013年05月16日 01:46