TOOL_テキストファイル情報収集_ファイル情報取得実行 - toolstorage

TOOL_テキストファイル情報収集_ファイル情報取得実行

• ソース

Option Compare Database
Option Explicit

' ファイル情報取得実行
' フォームのボタンを押下した際の処理を記述

' GetFileInfos
' 実行ボタン押下時の処理
' フォームの情報を取得し、ファイルを検索する
Public Function GetFileInfos()
    Dim FVObj As GFI_FormValueObject
    Dim FIObj As GFI_FileInfoObject
    Dim FileName As String
    
    ' 1.フォーム情報の取得
    Set FVObj = New GFI_FormValueObject
    
    ' 2.入力内容のバリデーションエラーを確認
    If FVObj.GetHasValiateError Then
        ' A.入力に不備がある場合、メッセージを表示
        MsgBox FVObj.GetValidateErrorMsg
    
    Else
    ' 3.入力に不備がない場合、ファイルの検索を行う
        FileName = Dir(FVObj.GetFolderPath & "\" & FVObj.GetFilePattern, vbNormal)
        
        ' 4.対象ファイルが存在していない場合、メッセージを出して処理を終了する
        If FileName = "" Then
            MsgBox "対象ファイルは存在しません"
            Exit Function
        End If
        
        ' 5.対象ファイルすべての情報を取得する
        Do While FileName <> ""
            ' A.ファイル情報取得クラスの初期化
            Set FIObj = New GFI_FileInfoObject
            
            ' A.1ファイル分の情報を取得する
            Call FIObj.InitFormInfo(FVObj)
            Call FIObj.GetFileInfo(FileName)
            
            ' B.取得した情報をレコードにして挿入
            Call FIObj.CreateInfoRecord
            
            ' C.次のファイルを検索
            FileName = Dir()
        Loop
            ' 6.正常完了メッセージを表示
            MsgBox "ファイル情報の取得が完了しました"
    End If
    
End Function

' ResetTableRecord
' 初期化実行ボタン押下時の処理
' 既に蓄積されたファイル情報を削除する
Public Function ResetTableRecord()
    Dim myDb As DAO.Database
    Dim strSQL As String
    Dim queryName As String
    
    ' 1.削除対象のテーブルのあるDBを設定
    Set myDb = CurrentDb
    
    ' 2.テーブル名を設定
    queryName = "ファイル情報リスト_初期化"
    
    ' 3.クエリ実行
    myDb.Execute queryName
     
End Function

2013/05/15 全面改訂

TOOL_テキストファイル情報収集

トップ