[cls]データベース操作 - DB DEV!!

クラスモジュール[clsDb]

Option Compare Database
Option Explicit

Dim objADOCON As New ADODB.Connection
Dim objADORS As New ADODB.Recordset

'DB接続
Private Sub Class_Initialize()
    Set objADOCON = Application.CurrentProject.Connection
End Sub

'DB切断
Private Sub Class_Terminate()
    On Error Resume Next
    objADOCON.Close
    objADORS.Close
    Set objADOCON = Nothing
    Set objADORS = Nothing
    On Error GoTo 0
End Sub

'SQL Select発行
Public Function ExecSelect(strSQL) As Boolean
    ExecSelect = False
    On Error Resume Next
    objADORS.CursorLocation = adUseClient
    objADORS.Open strSQL, objADOCON, adOpenForwardOnly, adLockReadOnly
    'SQL実行結果を判定
    If objADOCON.Errors.Count = 0 Then
     ExecSelect = True
    End If
    On Error GoTo 0
End Function

'SQL Select以外発行
Public Function ExecSQL(strSQL) As Boolean
    ExecSQL = False
    On Error Resume Next
    objADOCON.Execute strSQL
    'SQL実行結果を判定
    If objADOCON.Errors.Count = 0 Then
         ExecSQL = True
    End If
    On Error GoTo 0
End Function

'トランザクション開始
Public Sub BeginTrans()
    objADOCON.BeginTrans
End Sub

'トランザクション終了 コミット
Public Sub Commit()
    objADOCON.CommitTrans
End Sub

'トランザクション終了 ロールバック
Public Sub Rollback()
    objADOCON.RollbackTrans
End Sub

'レコードセット取得
Public Property Get GetRS() As ADODB.Recordset
    Set GetRS = objADORS
End Property